Comment field for Inventory Adjustments

Applies to:

SAP ECC 6.0 EHP 4

Summary

There are various options for posting inventory differences depending on the processing status of the physical inventory transaction.

Posting differences after the count has been posted

A physical inventory document has already been created, and the count has already been posted. You only have to post the inventory differences.

Posting the count and inventory differences simultaneously after the physical inventory document has been created

A physical inventory document has been created, but the count has not yet been posted. The count results are available. You enter the count and post the differences in one step.

Entering the count without a document reference

You have a count result without reference; that is, no physical inventory document has yet been created for this physical inventory transaction. You create a physical inventory document, enter the count, and post the differences in one step.

SAP provides transactions MI07, MI10 to post inventory difference. These transactions do not provide any ability to user to enter some free text to further explain the need to make any adjustments. For end user, it becomes much more easier to later on understand the reasons of inventory difference, if there is provision to enter free text. Entering comments also help to identify reasons for quant write-offs.

This document describes a work around developed in SAP to allow user to enter free text as inventory adjustment reason.

Author: Parag Parikh

Company: Deloitte Consulting LLP

Created on: 24th March 2012

Author Bio

Parag Parikh is an SAP ABAP, SAP workflow consultant with 4.5 years of experience. He has extensively worked on SAP ABAP and SAP workflow. Parag also has functional skills for SAP FS-CD solution. He has worked on many SAP modules including SAP FI/CO, SD, MM, QM, PP, PLM-RM, SRM, HCM, ESS/MSS and EH&S. Parag is working with Deloitte Consulting LLP as Workflow Specialist.

Author: Vamsi Krishna Parepalli ( SCN ID: E1106724)

Company: Deloitte Consulting LLP

Vamsi Parepalli has over 6 years of experience in SAP ABAP, SAP OO-ABAP. He has extensively worked on Object Oriented ABAP. Vamsi is a techno-functional expert in SAP Retail, SAP SD and SAP MM modules. His experience includes Reports, Enhancements, Forms, Interfaces and Workflow development. Vamsi is also an iRise expert and has developed many pre-sales demo using iRise Visual Simulator. He is currently working with Deloitte Consulting LLP as SAP Technical Consultant in capacity of a process lead and is technically leading iRise initiative. He is also responsible for implementing EH&S and Global Label Management solution for clients.

Document Created on: 1st March 2013

Requirement:

Provide user with ability to enter the free text on the below transaction screens.

MI10 – Post Document, Count and Differences: Initial Screen

MI07 – Post Inventory Difference: Initial Screen

Challenges:

1) SAP does not provide any screen entrancement option (BAdi, customer exit) for both the transactions on initial screen.

2) What if user needs to enter different adjustment comments for each material in stock?

Solution Proposed:

Instead of initial screen, provide an editable ALV screen when user press SAVE button with details of all materials for which count is adjusted. An assumption is made that reason comment will be less than or equal to 100 characters.

If needed the approach can be modified to publish a long text editor in pop-up for each row in ALV to enter long text.

Demonstration:

Below section describes behavior of enhanced transaction once development was in place.

MI10:

I. Perform inventory adjustment w/o reference (via MI10)

Go to MI10 transaction (Post, Count, and Difference).

Enter the material, batch, inventory count, reason code and save the record.

Below is new screen created to allow user to enter reason text for each line entered on screen above. For user's reference, the ALV screen also provides Material Description, Plant, Storage Location, Batch, Special Indicator, Stock Type information as well in addition to provision to edit Reason Comment.

Check the data posted in ISEG table.

We see that comment is updated in table ISEG in custom field of 100 characters.

II. Create inventory document (via MI01).

Create a Physical inventory document in MI01 transaction.

Enter the material number and the batch and save the inventory record.

Enter the inventory count in MI04 transaction.

Enter the inventory count and save the physical inventory document.

Post the inventory difference in MI07 transaction.

Enter the reason code and hit SAVE.

Custom screen to enter rejection comments is displayed.

III. Execute MI07, using inventory record from case II.

Create a System inventory record using transaction LI01.

Enter the storage bin value and save the system inventory record.

Activate the record using LI02 transaction.

Enter the count in the inventory record using LI11 transaction.

Clear the Storage bin associated with the inventory record using LI20 transaction.

Post the inventory record in LI21 transaction entering the reason code comment.

As shown below, custom screen is displayed to provide reason text. This time user can enter reason for write-off reason for a particular inventory item.

Technical Approach:

To create a custom screen, a custom function group can be created. Function Modules inside this Function Group can then call the custom screen using familiar CALL SCREEN command.

FM to display ALV:

To display an editable ALV, we can encapsulate ALV code in a FM. create a function group ZFSIM_INV. Create a custom function module ‘ZFSIM_INV_REASON_COMMENT’. Code snippet below provides details on FM implementation.

FUNCTION zfsim_inv_reason_comment.

*"----------------------------------------------------------------------

*"*"Local Interface:

*" TABLES

*" CT_ISEG STRUCTURE ISEG

*"----------------------------------------------------------------------

TYPES: BEGIN OF ty_mat_text,

matnr TYPE matnr,

maktx TYPE maktx,

END OF ty_mat_text,

tt_mat_text TYPE STANDARD TABLE OF ty_mat_text.

DATA: lt_mat TYPE tt_mat_text.

FIELD-SYMBOLS: <lfs_mat> TYPE LINE OF tt_mat_text.

SELECT matnr maktx

INTO TABLE lt_mat

FROM makt

FOR ALL ENTRIES IN ct_iseg

WHERE matnr = ct_iseg-matnr

AND spras = sy-langu.

IF sy-subrc EQ 0.

SORT lt_mat BY matnr.

ENDIF.

IF NOT ct_iseg[] IS INITIAL.

LOOP AT ct_iseg ASSIGNING <lfs_iseg>.

ls_iseg-zeili = <lfs_iseg>-zeili.

ls_iseg-matnr = <lfs_iseg>-matnr.

READ TABLE lt_mat ASSIGNING <lfs_mat>

WITH KEY matnr = <lfs_iseg>-matnr

BINARY SEARCH.

IF sy-subrc EQ 0.

ls_iseg-maktx = <lfs_mat>-maktx.

ENDIF.

ls_iseg-lgort = <lfs_iseg>-lgort.

ls_iseg-werks = <lfs_iseg>-werks.

ls_iseg-charg = <lfs_iseg>-charg.

ls_iseg-sobkz = <lfs_iseg>-sobkz.

ls_iseg-bstar = <lfs_iseg>-bstar.

APPEND ls_iseg TO lt_iseg.

CLEAR ls_iseg.

ENDLOOP.

IF NOT lt_iseg[] IS INITIAL.

PERFORM f_alv_display CHANGING lt_iseg.

ENDIF.

IF NOT lt_iseg[] IS INITIAL.

CLEAR ls_iseg.

LOOP AT lt_iseg INTO ls_iseg.

READ TABLE ct_iseg ASSIGNING <lfs_iseg> WITH KEY

zeili = ls_iseg-zeili.

IF sy-subrc EQ 0.

<lfs_iseg>-reas_comm = ls_iseg-reas.

ENDIF.

ENDLOOP.

ENDIF.

ENDFUNCTION.

Top include and subroutine include for the function group:

*&---------------------------------------------------------------------*

*& Form F_ALV_DISPLAY

*&---------------------------------------------------------------------*

* To display the data in the ALV format

*----------------------------------------------------------------------*

* --> p1 text

* <-- p2 text

*----------------------------------------------------------------------*

FORM f_alv_display CHANGING ct_iseg TYPE tt_iseg.

DATA: lt_fieldcat TYPE slis_t_fieldcat_alv,

lt_events TYPE slis_t_event,

ls_layout TYPE slis_layout_alv.

*&-- Build Fieldcatalog for ALV display

PERFORM f_build_fieldcat CHANGING lt_fieldcat.

*&-- Build the event table for the ALV Display

PERFORM f_build_events CHANGING lt_events.

*&-- Build the layout table for ALV Display

PERFORM f_build_layout CHANGING ls_layout.

*&-- Perform to display the output

PERFORM f_alv_output USING lt_fieldcat

lt_events

ls_layout

ct_iseg.

ENDFORM. " F_ALV_DISPLAY

*&---------------------------------------------------------------------*

*& Form F_BUILD_FIELDCAT

*&---------------------------------------------------------------------*

* Building the Fieldcatalog Table for Display of ALV

*----------------------------------------------------------------------*

* --> p1 text

* <-- p2 text

*----------------------------------------------------------------------*

FORM f_build_fieldcat CHANGING pct_fieldcat TYPE slis_t_fieldcat_alv.

CONSTANTS: lc_1 TYPE sycucol VALUE '1',

lc_2 TYPE sycucol VALUE '2',

lc_3 TYPE sycucol VALUE '3',

lc_4 TYPE sycucol VALUE '4',

lc_5 TYPE sycucol VALUE '5',

lc_6 TYPE sycucol VALUE '6',

lc_7 TYPE sycucol VALUE '7',

lc_8 TYPE sycucol VALUE '8',

lc_9 TYPE sycucol VALUE '9',

lc_100 TYPE outputlen VALUE '100',

lc_zeili TYPE slis_fieldname VALUE 'ZEILI',

lc_matnr TYPE slis_fieldname VALUE 'MATNR',

lc_werks TYPE slis_fieldname VALUE 'WERKS',

lc_lgort TYPE slis_fieldname VALUE 'LGORT',

lc_charg TYPE slis_fieldname VALUE 'CHARG',

lc_sobkz TYPE slis_fieldname VALUE 'SOBKZ',

lc_bstar TYPE slis_fieldname VALUE 'BSTAR',

lc_reas TYPE slis_fieldname VALUE 'REAS',

lc_maktx TYPE slis_fieldname VALUE 'MAKTX',

lc_table TYPE slis_tabname VALUE 'PT_ISEG'.

DATA: ls_fieldcat TYPE slis_fieldcat_alv.

ls_fieldcat-col_pos = lc_1.

ls_fieldcat-fieldname = lc_zeili.