Technical Design:

MVC Design Document for Volume Estimation for Cross dock deliveries:

Development Navigation:

Executable Program:

  Program Name: ZDL_VOLUME_ESTIMATION:

Code details

**********************************************************************
* Date          Username  Chg Req/Incident      Description
* 16.10.2014    BISWAJO  U148 Transportation  Volume estimation for
*                        Portal                cross dock deliveries
*
**********************************************************************
*&---------------------------------------------------------------------*
*& Report  ZMD_VOLUME_ESTIMATION
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*

REPORT zdl_volume_estimation.

***Data Declaration
INCLUDE zdl_volume_estimation_dd.
*INCLUDE zmd_volume_estimation_dd.

***Selection-Screen
INCLUDE zdl_volume_estimation_ss.
*INCLUDE zmd_volume_estimation_ss.


START-OF-SELECTION.

***Validate the selection Screen
PERFORM screen_validate.

*Get instance
go_volume_estimation = zcl_dl_vol_estimation_model=>get_instance( ).

*Set filter
go_volume_estimation->set_filter(
i_delivery  = dl_ty_so[]                                  "Delivery Type
i_tr_group  = tr_gr_so[]                                  "Transportation Group
i_cr_date    = cr_dt_so[]                                  "Date on Which Record Was Created
i_cr_time    = cr_tm_so[]                                  "Entry time
i_shp_pnt    = sh_pt_so[]                                  "Shipping Point/Receiving Point
i_route      = route_so[]                                  "Route
i_dlv_num    = dv_nr_so[]                                  "Delivery
i_test_run  = ts_run_p ) .                                "Checkbox for Test Run

go_volume_estimation->retrieve_ve_details( ).
go_volume_estimation->populate_final_table( ).
go_volume_estimation->puopulate_field_catalog( ).
go_volume_estimation->display_output_in_alv( ).

Include Name: ZDL_VOLUME_ESTIMATION_DD:

Code details

**********************************************************************
* Date          Username  Chg Req/Incident      Description
* 16.10.2014    BISWAJO  U148 Transportation  Volume estimation for
*                        Portal                cross dock deliveries
*                                              TOP INCLUDE
**********************************************************************
*&---------------------------------------------------------------------*
*&  Include          ZMD_VOLUME_ESTIMATION_DD
*&---------------------------------------------------------------------*
TABLES: likp.

DATA: dl_ty_so_lv TYPE lfart,                  "Delivery Type
tr_gr_so_lv TYPE tragr,                  "Transportation Group
cr_dt_so_lv TYPE erdat,                  "Date on Which Record Was Created
cr_tm_so_lv TYPE erzet,                  "Entry time
sh_pt_so_lv TYPE vstel,                  "Shipping Point/Receiving Point
route_so_lv TYPE route,                  "Route
dv_nr_so_lv TYPE vbeln_vl.                "Delivery

DATA: go_volume_estimation TYPE REF TO zcl_dl_vol_estimation_model.

Include Name: ZDL_VOLUME_ESTIMATION_SS:

Code details

**********************************************************************
* Date          Username  Chg Req/Incident      Description
* 17.10.2014    BISWAJO  U148 Transportation  Volume estimation for
*                        Portal                cross dock deliveries
*                                              SELECTION-SCREEN
**********************************************************************
*&---------------------------------------------------------------------*
*&  Include          ZMD_VOLUME_ESTIMATION_SS
*&---------------------------------------------------------------------*
SELECTION-SCREEN: BEGIN OF BLOCK b1 WITH FRAME TITLE text-000.
SELECT-OPTIONS: dl_ty_so    FOR likp-lfart    NO INTERVALS OBLIGATORY,              "Delivery Type
tr_gr_so    FOR likp-tragr    NO INTERVALS OBLIGATORY,              "Transportation Group
cr_dt_so    FOR likp-erdat    NO INTERVALS NO-EXTENSION DEFAULT SY-DATUM,  "Date on Which Record Was Created
cr_tm_so    FOR likp-erzet    NO-EXTENSION ,              "Entry time
sh_pt_so    FOR likp-vstel    NO INTERVALS,                          "Shipping Point/Receiving Point
route_so    FOR likp-route    NO INTERVALS,                          "Route
dv_nr_so    FOR likp-vbeln    .                          "Delivery
PARAMETERS:    ts_run_p    AS  CHECKBOX.
SELECTION-SCREEN: END OF BLOCK b1.
*&---------------------------------------------------------------------*
*&      Form  SCREEN_VALIDATE
*&---------------------------------------------------------------------*
*      text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM screen_validate .

**** Validating User Inputs for the Selection Screen

IF NOT dl_ty_so-low IS INITIAL.
SELECT SINGLE lfart
FROM likp
INTO dl_ty_so_lv
WHERE lfart EQ dl_ty_so-low.      "#EC WARNOK
*          WHERE lfart IN dl_ty_so.      "#EC WARNOK

IF sy-subrc NE 0.
MESSAGE text-001 TYPE 'I'.
STOP.
ENDIF.
ENDIF.
CLEAR dl_ty_so_lv.

IF NOT tr_gr_so-low IS INITIAL.
SELECT SINGLE tragr
FROM likp
INTO tr_gr_so_lv
*            WHERE tragr IN tr_gr_so.    "#EC WARNOK
WHERE tragr EQ tr_gr_so-low.    "#EC WARNOK

IF sy-subrc NE 0.
MESSAGE text-001 TYPE 'I'.
STOP.
ENDIF.
ENDIF.
CLEAR dl_ty_so_lv.

IF cr_dt_so-low IS INITIAL.
cr_dt_so-low  = sy-datum.
ENDIF.

IF NOT cr_dt_so-low IS INITIAL.
SELECT SINGLE erdat
FROM likp
INTO cr_dt_so_lv
*          WHERE erdat IN cr_dt_so.      "#EC WARNOK
WHERE erdat EQ cr_dt_so-low.      "#EC WARNOK

IF sy-subrc NE 0.
MESSAGE text-002 TYPE 'I'.
STOP.
ENDIF.
ENDIF.
CLEAR cr_dt_so_lv.

IF cr_tm_so-low IS INITIAL.
cr_tm_so-low = 000000.
ENDIF.

IF NOT cr_tm_so-low IS INITIAL.
SELECT SINGLE erzet
FROM likp
INTO cr_tm_so_lv
WHERE erzet EQ cr_tm_so-low.        "#EC WARNOK

IF sy-subrc NE 0.
MESSAGE text-003 TYPE 'I'.
STOP.
ENDIF.
ENDIF.
CLEAR cr_tm_so_lv.


IF NOT cr_tm_so-high IS INITIAL.
SELECT SINGLE erzet
FROM likp
INTO cr_tm_so_lv
WHERE erzet EQ cr_tm_so-high.        "#EC WARNOK

IF sy-subrc NE 0.
MESSAGE text-003 TYPE 'I'.
STOP.
ENDIF.
ENDIF.
CLEAR cr_tm_so_lv.

IF NOT sh_pt_so-low IS INITIAL.
SELECT SINGLE vstel
FROM likp
INTO sh_pt_so_lv
WHERE vstel EQ sh_pt_so-low.          "#EC WARNOK

IF sy-subrc NE 0.
MESSAGE text-004 TYPE 'I'.
STOP.
ENDIF.
ENDIF.
CLEAR sh_pt_so_lv.

IF NOT route_so-low IS INITIAL.
SELECT SINGLE route
FROM likp
INTO route_so_lv
WHERE route EQ route_so-low.          "#EC WARNOK

IF sy-subrc NE 0.
MESSAGE text-005 TYPE 'I'.
STOP.
ENDIF.
ENDIF.
CLEAR route_so_lv.

IF NOT dv_nr_so-low IS INITIAL.
SELECT SINGLE vbeln
FROM likp
INTO dv_nr_so_lv
WHERE vbeln EQ dv_nr_so-low.          "#EC WARNOK

IF sy-subrc NE 0.
MESSAGE text-006 TYPE 'I'.
STOP.
ENDIF.
ENDIF.
CLEAR dv_nr_so_lv.

IF NOT dv_nr_so-high IS INITIAL.
SELECT SINGLE vbeln
FROM likp
INTO dv_nr_so_lv
WHERE vbeln EQ dv_nr_so-high.          "#EC WARNOK

IF sy-subrc NE 0.
MESSAGE text-006 TYPE 'I'.
STOP.
ENDIF.
ENDIF.
CLEAR dv_nr_so_lv.

ENDFORM.                    " SCREEN_VALIDATE

Class Definition and Details:

  Global Model Class: ZCL_DL_VOL_ESTIMATION_MODEL:

Source CodeBased Class Builder:

class ZCL_DL_VOL_ESTIMATION_MODEL definition
public
final
create public .

public section.

types:
BEGIN OF VOLUME_ESTIMATION_FINAL_TYPES,
MANDT                  TYPE    MANDT,
SHIPPING_POINT          TYPE    VSTEL,
ROUTE                  TYPE    ROUTE,
ROUTE_SCHEDULE          TYPE    AULWE,
CUSTOMER_NUMBER        TYPE    KUNNR,
TRAN_GROUP              TYPE    TRAGR,
PACK_MAT_NO            TYPE    VHILM,
COUNTER                TYPE    Char3,
LICENSE_PLATE          TYPE    ZLICENCE_PLATE,
DEST_ZONE              TYPE    LZONE,
DEPA_ZONE              TYPE    AZONE,
STATUS                  TYPE    ZSTATUS,
DROPPING_SEQUENCE(5)    TYPE    C,
*        DROPPING_SEQUENCE      TYPE    AUSL_REIH,
FREIGHT_GROUP          TYPE    MFRGR,
DOOR                    TYPE    ZDOOR,
DELIVERY_DATE          TYPE    LFDAT,
DELIVERY_TIME          TYPE    LFUHR,
ISSUE_DATE              TYPE    WADAK,
ISSUE_TIME              TYPE    WAUHR,
CUSTOMER_NAME          TYPE    NAME1_GP,
HUB_CARRIER_ID          TYPE    ZCARRIER,
HUB_CARRIER_NAME        TYPE    NAME1_GP,
CARRIER_ID              TYPE    ZCARRIER,
CARRIER_NAME            TYPE    NAME1_GP,
AMOUNT                  TYPE    ZAMOUNT,
WEIGHT                  TYPE    BRGEW,
WEIGHT_UOM              TYPE    GEWEI,
END OF VOLUME_ESTIMATION_FINAL_TYPES .
types:
range_delivery  TYPE RANGE OF lfart .
types:
range_tr_group  TYPE RANGE OF tragr .
types:
range_cr_date    TYPE RANGE OF erdat .
types:
range_cr_time    TYPE RANGE OF erzet .
types:
range_shp_pnt    TYPE RANGE OF vstel .
types:
range_route      TYPE RANGE OF route .
types:
range_dlv_num    TYPE RANGE OF vbeln_vl .
types:
VOLUME_ESTIMATE_FINAL_TABLE TYPE STANDARD TABLE OF VOLUME_ESTIMATION_FINAL_TYPES .

data VOLUME_ESTIMATE_FINAL_T type VOLUME_ESTIMATE_FINAL_TABLE .
type-pools SLIS .
data FIELDCATALOG_T type SLIS_T_FIELDCAT_ALV .
data LO_VE_CONTROL type ref to ZCL_DL_VOL_ESTIMATION_CONTROL .

methods SET_FILTER
importing
!I_DELIVERY type RANGE_DELIVERY
!I_TR_GROUP type RANGE_TR_GROUP
!I_CR_DATE type RANGE_CR_DATE
!I_CR_TIME type RANGE_CR_TIME
!I_SHP_PNT type RANGE_SHP_PNT
!I_ROUTE type RANGE_ROUTE
!I_DLV_NUM type RANGE_DLV_NUM
!I_TEST_RUN type CHAR1 .
class-methods GET_INSTANCE
returning
value(R_VE_MODEL) type ref to ZCL_DL_VOL_ESTIMATION_MODEL .
methods PUOPULATE_FIELD_CATALOG .
methods DISPLAY_OUTPUT_IN_ALV .
methods RETRIEVE_VE_DETAILS .
methods POPULATE_FINAL_TABLE .
PROTECTED SECTION.
PRIVATE SECTION.

TYPES:
BEGIN OF filter_type_ve,
delivery        TYPE range_delivery,
tr_group        TYPE range_tr_group,
cr_date          TYPE range_cr_date,
cr_time          TYPE range_cr_time,
shp_pnt          TYPE range_shp_pnt,
route            TYPE range_route,
dlv_num          TYPE range_dlv_num,
test_run_flag    TYPE char1,
END OF filter_type_ve .

CLASS-DATA ve_model TYPE REF TO zcl_dl_vol_estimation_model .
DATA filter TYPE filter_type_ve .
DATA ve_list TYPE zdl_volum_estimate_list_type .
ENDCLASS.



CLASS ZCL_DL_VOL_ESTIMATION_MODEL IMPLEMENTATION.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method ZCL_DL_VOL_ESTIMATION_MODEL->DISPLAY_OUTPUT_IN_ALV
* +-------------------------------------------------------------------------------------------------+
* +--------------------------------------------------------------------------------------</SIGNATURE>
METHOD display_output_in_alv.

**********************************************************************
* Date          Username  Chg Req/Incident      Description
* 21.10.2014    BISWAJO  U148 Transportation  Volume estimation for
*                        Portal                cross dock deliveries
*
**********************************************************************
DATA: repid_v      TYPE      sy-repid.

****Displaying Output in ALV Format****

repid_v  = sy-repid.



IF volume_estimate_final_t IS NOT INITIAL.

CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
EXPORTING
i_callback_program = repid_v
*        i_callback_top_of_page  = me->TOP_OF_PAGE
it_fieldcat        = fieldcatalog_t[]
TABLES
t_outtab          = volume_estimate_final_t.


ENDIF.

ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Static Public Method ZCL_DL_VOL_ESTIMATION_MODEL=>GET_INSTANCE
* +-------------------------------------------------------------------------------------------------+
* | [<-()] R_VE_MODEL                    TYPE REF TO ZCL_DL_VOL_ESTIMATION_MODEL
* +--------------------------------------------------------------------------------------</SIGNATURE>
METHOD get_instance.

**********************************************************************
* Date          Username  Chg Req/Incident      Description
* 22.10.2014    BISWAJO  U148 Transportation  Volume estimation for
*                        Portal                cross dock deliveries
*
**********************************************************************

**** Creating instance of the model class****

IF ve_model IS INITIAL.
CREATE OBJECT ve_model.
ENDIF.

r_ve_model = ve_model.

ENDMETHOD.                    "get_instance


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method ZCL_DL_VOL_ESTIMATION_MODEL->POPULATE_FINAL_TABLE
* +-------------------------------------------------------------------------------------------------+
* +--------------------------------------------------------------------------------------</SIGNATURE>
METHOD populate_final_table.

**********************************************************************
* Date          Username  Chg Req/Incident      Description
* 21.10.2014    BISWAJO  U148 Transportation  Volume estimation for
*                        Portal                cross dock deliveries
*
**********************************************************************

DATA: ve_list_row  LIKE LINE OF me->ve_list.
DATA: ve_obj      TYPE REF TO zcl_dl_vol_estimation_control,
volume_estimation_final_s TYPE volume_estimation_final_types.

LOOP AT me->ve_list INTO ve_list_row.

ve_obj = ve_list_row-vol_estimate.
volume_estimation_final_s-mandt              = ve_obj->mandt.                  "Client
volume_estimation_final_s-shipping_point      = ve_obj->shipping_point.        "Shipping Point/Receiving Point
volume_estimation_final_s-route              = ve_obj->route.                  "Route
volume_estimation_final_s-route_schedule      = ve_obj->route_schedule.        "Route Schedule
volume_estimation_final_s-customer_number    = ve_obj->customer_number.        "Customer Number
volume_estimation_final_s-tran_group          = ve_obj->tran_group.            "Transportation Group
volume_estimation_final_s-pack_mat_no        = ve_obj->pack_mat_no.            "Packaging Materials
volume_estimation_final_s-counter            = ve_obj->counter.                "Counter
volume_estimation_final_s-status              = ve_obj->status.                "Status of the Record
volume_estimation_final_s-dropping_sequence  = ve_obj->dropping_sequence.      "Dropping Sequence
volume_estimation_final_s-freight_group      = ve_obj->freight_group.          "Article freight group
volume_estimation_final_s-depa_zone          = ve_obj->depa_zone.              "Departure zone
volume_estimation_final_s-dest_zone          = ve_obj->dest_zone.              "Transportation zone to or from which the goods are delivered
volume_estimation_final_s-delivery_date      = ve_obj->delivery_date.          "Delivery date
volume_estimation_final_s-delivery_time      = ve_obj->delivery_time.          "Time of delivery
volume_estimation_final_s-issue_date          = ve_obj->issue_date.            "Goods Issue Date
volume_estimation_final_s-issue_time          = ve_obj->issue_time.            "Time of Goods Issue (Local, Relating to a Site)
volume_estimation_final_s-customer_name      = ve_obj->customer_name.          "Name 1
volume_estimation_final_s-hub_carrier_id      = ve_obj->hub_carrier_id.        "Carrier ID
volume_estimation_final_s-hub_carrier_name    = ve_obj->hub_carrier_name.      "Name 1
volume_estimation_final_s-carrier_id          = ve_obj->carrier_id.            "Carrier ID
volume_estimation_final_s-carrier_name        = ve_obj->carrier_name.          "Name 1
volume_estimation_final_s-amount              = ve_obj->amount.                "Amount
volume_estimation_final_s-weight              = ve_obj->weight.                "Gross Weight
volume_estimation_final_s-weight_uom          = ve_obj->weight_uom.            "Weight Unit


APPEND volume_estimation_final_s TO volume_estimate_final_t.
CLEAR volume_estimation_final_s.

ENDLOOP.

ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method ZCL_DL_VOL_ESTIMATION_MODEL->PUOPULATE_FIELD_CATALOG
* +-------------------------------------------------------------------------------------------------+
* +--------------------------------------------------------------------------------------</SIGNATURE>
METHOD puopulate_field_catalog.

**********************************************************************
* Date          Username  Chg Req/Incident      Description
* 22.10.2014    BISWAJO  U148 Transportation  Volume estimation for
*                        Portal                cross dock deliveries
*
**********************************************************************

DATA: fieldcat_s      TYPE slis_fieldcat_alv.

CONSTANTS: co_mandt                TYPE char30  VALUE 'MANDT',                      "Client
co_shipping_point        TYPE char30  VALUE 'SHIPPING_POINT',            "Shipping Point/Receiving Point
co_route                TYPE char30  VALUE 'ROUTE',                      "Route
co_route_schedule        TYPE char30  VALUE 'ROUTE_SCHEDULE',            "Route Schedule
co_customer_number      TYPE char30  VALUE 'CUSTOMER_NUMBER',            "Customer Number
co_tran_group            TYPE char30  VALUE 'TRAN_GROUP',                "Transportation Group
co_pack_mat_no          TYPE char30  VALUE 'PACK_MAT_NO',                "Packaging Materials
co_counter_name          TYPE char10  VALUE 'COUNTER',                    "Counter
co_issue_date            TYPE char30  VALUE 'ISSUE_DATE',                "Goods Issue Date
co_license_plate        TYPE char30  VALUE 'LICENSE_PLATE',              "Vehicle Licence Plate
co_dest_zone            TYPE char30  VALUE 'DEST_ZONE',                  "Transportation zone to or from which the goods are delivered
co_depa_zone            TYPE char30  VALUE 'DEPA_ZONE',                  "Departure zone
co_status                TYPE char30  VALUE 'STATUS',                    "Status of the Record
co_dropping_sequence    TYPE char30  VALUE 'DROPPING_SEQUENCE',          "Dropping Sequence
co_freight_group        TYPE char30  VALUE 'FREIGHT_GROUP',              "Article freight group
co_door                  TYPE char30  VALUE 'DOOR',                      "Door Information
co_delivery_date        TYPE char30  VALUE 'DELIVERY_DATE',              "Delivery date
co_delivery_time        TYPE char30  VALUE 'DELIVERY_TIME',              "Time of delivery
co_issue_time            TYPE char30  VALUE 'ISSUE_TIME',                "Time of Goods Issue (Local, Relating to a Site)
co_customer_name        TYPE char30  VALUE 'CUSTOMER_NAME',              "Name 1
co_hub_carrier_id        TYPE char30  VALUE 'HUB_CARRIER_ID',            "Carrier ID
co_hub_carrier_name      TYPE char30  VALUE 'HUB_CARRIER_NAME',          "Name 1
co_carrier_id            TYPE char30  VALUE 'CARRIER_ID',                "Carrier ID
co_carrier_name          TYPE char30  VALUE 'CARRIER_NAME',              "Name 1
co_amount                TYPE char30  VALUE 'AMOUNT',                    "Amount
co_weight                TYPE char30  VALUE 'WEIGHT',                    "Gross Weight
weight_uom              TYPE char30  VALUE 'WEIGHT_UOM'.                "Weight Unit

**Start of Processing
**Defne Macro for fieldcat

DEFINE fieldcat.
fieldcat_s-col_pos  = &1.
fieldcat_s-fieldname = &2.
fieldcat_s-seltext_l = &3.
append fieldcat_s to fieldcatalog_t.
clear fieldcat_s .
END-OF-DEFINITION.

fieldcat '1'  co_mandt                  text-001 .                                    "Client
fieldcat '2'  co_shipping_point        text-002 .                                    "Shipping Point/Receiving Point
fieldcat '3'  co_route                  text-003 .                                    "Route
fieldcat '4'  co_route_schedule        text-004 .                                    "Route Schedule
fieldcat '5'  co_customer_number        text-005 .                                    "Customer Number
fieldcat '6'  co_tran_group            text-006 .                                    "Transportation Group
fieldcat '7'  co_pack_mat_no            text-007 .                                    "Packaging Materials
fieldcat '8'  co_counter_name          text-008 .                                    "Counter
fieldcat '9'  co_issue_date            text-009 .                                    "Goods Issue Date
fieldcat '10' co_license_plate          text-010 .                                    "Vehicle Licence Plate
fieldcat '11' co_dest_zone              text-011 .                                    "Transportation zone to or from which the goods are delivered
fieldcat '12' co_depa_zone              text-012 .                                    "Departure zone
fieldcat '13' co_status                text-013 .                                    "Status of the Record
fieldcat '14' co_dropping_sequence      text-014 .                                    "Dropping Sequence
fieldcat '15' co_freight_group          text-015 .                                    "Article freight group
fieldcat '16' co_door                  text-016 .                                    "Door Information
fieldcat '17' co_delivery_date          text-017 .                                    "Delivery date
fieldcat '18' co_delivery_time          text-018 .                                    "Time of delivery
fieldcat '19' co_issue_time            text-019 .                                    "Time of Goods Issue (Local, Relating to a Site)
fieldcat '20' co_customer_name          text-020 .                                    "Name 1
fieldcat '21' co_hub_carrier_id        text-021 .                                    "Carrier ID
fieldcat '22' co_hub_carrier_name      text-022 .                                    "Name 1
fieldcat '23' co_carrier_id            text-023 .                                    "Carrier ID
fieldcat '24' co_carrier_name          text-024 .                                    "Name 1
fieldcat '25' co_amount                text-025 .                                    "Amount
fieldcat '26' co_weight                text-026 .                                    "Gross Weight
fieldcat '27' weight_uom                text-027 .                                    "Weight Unit


ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method ZCL_DL_VOL_ESTIMATION_MODEL->RETRIEVE_VE_DETAILS
* +-------------------------------------------------------------------------------------------------+
* +--------------------------------------------------------------------------------------</SIGNATURE>
METHOD retrieve_ve_details.

**********************************************************************
* Date          Username  Chg Req/Incident      Description
* 21.10.2014    BISWAJO  U148 Transportation  Volume estimation for
*                        Portal                cross dock deliveries
*
**********************************************************************

CREATE OBJECT lo_ve_control.
me->ve_list = lo_ve_control->get_volume_estimation_details( me->filter ).
ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method ZCL_DL_VOL_ESTIMATION_MODEL->SET_FILTER
* +-------------------------------------------------------------------------------------------------+
* | [--->] I_DELIVERY                    TYPE        RANGE_DELIVERY
* | [--->] I_TR_GROUP                    TYPE        RANGE_TR_GROUP
* | [--->] I_CR_DATE                      TYPE        RANGE_CR_DATE
* | [--->] I_CR_TIME                      TYPE        RANGE_CR_TIME
* | [--->] I_SHP_PNT                      TYPE        RANGE_SHP_PNT
* | [--->] I_ROUTE                        TYPE        RANGE_ROUTE
* | [--->] I_DLV_NUM                      TYPE        RANGE_DLV_NUM
* | [--->] I_TEST_RUN                    TYPE        CHAR1
* +--------------------------------------------------------------------------------------</SIGNATURE>
METHOD set_filter.

**********************************************************************
* Date          Username  Chg Req/Incident      Description
* 22.10.2014    BISWAJO  U148 Transportation  Volume estimation for
*                        Portal                cross dock deliveries
*
**********************************************************************

me->filter-delivery        = i_delivery.                    "Delivery Type
me->filter-tr_group        = i_tr_group.                    "Transportation Group
me->filter-cr_date        = i_cr_date.                    "Date on Which Record Was Created
me->filter-cr_time        = i_cr_time.                    "Entry time
me->filter-shp_pnt        = i_shp_pnt.                    "Shipping Point/Receiving Point
me->filter-route          = i_route.                      "Route
me->filter-dlv_num        = i_dlv_num.                    "Delivery
me->filter-test_run_flag  = i_test_run.                    "Checkbox for Test Run

ENDMETHOD.                    "SET_FILTER
ENDCLASS.

This will call the Controller class to provide the fetching logic and by using Persistent class, it will update the Database table as well as Log Table.

Thanks & Regards,

Joyjit Biswas